Macromedia Flash Professional 8 UNLEASHED [Electronic resources] نسخه متنی

The BlurFilter Class

The BlurFilter class is designed to create blurred image effects on objects.

It is important when using this class to import it first at the beginning of your script, like this:

import flash.filters.BlurFilter;

To instantiate a new instance of the BlurFilter class, use this code as a template:

var myFilter:BlurFilter = new BlurFilter(blurX, blurY, quality);

• blurX
  The total amount of horizontal blur from 0255. Default value of 4.0.

• blurY
  The total amount of vertical blur from 0255. Default value of 4.0.

• quality
  This number represents the number of times to apply the filter ranging from 015. Default value of 1.

Example :

This example will create a small blue square using the drawing API and apply the filter to it:

import flash.filters.BlurFilter;
//create the movie clip to display the filter
var rec_mc:MovieClip = this.createEmptyMovieClip("rec_mc", 1);
//move the rectangle towards the center of the stage
rec_mc._x = rec_mc._y = 200;
//draw a squar inside the movie clip
rec_mc.lineStyle(0,0x000000,0);
rec_mc.beginFill(0x397dce, 100);
rec_mc.lineTo(100,0);
rec_mc.lineTo(100,100);
rec_mc.lineTo(0,100);
rec_mc.lineTo(0,0);
rec_mc.endFill();
//create the filter
var myFilter:BlurFilter = new BlurFilter(10, 10, 3);
//apply the filter
rec_mc.filters = new Array(myFilter);

Because the properties of this object match the parameters identically, they will be skipped.

Methods

clone

Availability :
FP:8, AS:1.0

Generic Template :
myFilter.clone()

Returns :
BevelFilter

An exact copy of the BlurFilter will be returned.

Description:

This method will create a duplicate copy of the BlurFilter it is called on.

Example:

This example will create a filter, clone it, then walk through all the properties to see that they match:

import flash.filters.BlurFilter;
//create the filter
var myFilter:BlurFilter = new BlurFilter(10, 10, 3);
//create a copy
var myNewFilter:BlurFilter = myFilter.clone();
//walk through and display each property
for(each in myNewFilter){
trace(each + ": " + myNewFilter[each]);
}
//output:clone: [type Function]
//quality: 3
//blurY: 10
//blurX: 10