Embedded Visual Basic Windows Ce And Pocket Pc Mobile Applications [Electronic resources] نسخه متنی

eMbedded Visual Basic®: Windows® CE and Pocket PC Mobile Applications

By
Chris Tacke, Timothy Bassett

Table of ContentsChapter 6.
The Pocket Outlook Object Model: Accessing Contacts and Calendar Items

Creating the Pocket PIM Sample Application

The sample application for this chapter is Pocket PIM, a version of the native PIM applications with a few twists. Although it's not intended to replace the powerful PIM applications, it presents some interesting features.

This sample application is intended to give a detailed understanding of the more commonly used functionality of POOM. Its design is also intended to give a general understanding of the style to work with POOM.

Pocket PIM features a Contact Grid (see Figure 6.2), an Appointment Grid (see Figure 6.3), and a Task Grid (see Figure 6.4). Each grid can be sorted by any of the displayed fields.

Figure 6.2. The Contacts Form. Notice that the vertical scroll is different from the typical vertical grid scrollbar.

Figure 6.3. The Tasks Form can be sorted by any of the displayed fields.

Figure 6.4. The Appointments Form provides a completely different view of appointments from the native PIM.

Other Technologies Demonstrated

Although not the focus of the chapter, pay attention to two other technologies or architectural styles used in the Pocket PIM application.

First, the manual paging technique used for the grids in the application. When building Pocket PIM, my device had more than 1,000 contacts present. Populating a grid with 1,000 records can be a poorly performing process. The power of the Pocket PC operating system is impressive, especially with a StrongArm processor, but there are limitations and the controls can become sluggish when consuming large amounts of data.

The grids are populated by using a manual-paging method that populates only the rows visible to users. The vertical scrollbar isn't visible, but a vertical scrollbar control is added in its place.

The second technology used is the ability to distinguish between a tap on the grid and whether the stylus is being held down to present a pop-up menu. This is accomplished by using the AsyncKeyState API call.

Building the Application

When first starting the project, be sure to set the reference to the PIMSTORE.DLL as instructed earlier. Let's start by creating the module modGlobal.bas.

modGlobal: Const, Global Objects, and Declares

Add a module named modGlobal to the project. The entire module is shown in Listing 6.6, but the most important aspect is to get the gobjPoom declared. You can create it all now, load it from the book resource files, or create it as you go.

Listing 6.6 modGlobal.bas: Public Variables, Consts, and API Declarations


Option Explicit
Public gobjPoom As PocketOutlook.Application
' number of rows in the contact grid
Public Const CONTACT_CONTACTGRID_ROWS = 13
' used as the captions for the contact grid's "header" row
Public Const CONTACTGRID_HEADER_FILEAS = "File As"
Public Const CONTACTGRID_HEADER_LASTNAME = "Last Name"
Public Const CONTACTGRID_HEADER_FIRSTNAME = "First Name"
Public Const CONTACTGRID_HEADER_COMPANYNAME = "Company Name"
Public Const CONTACTGRID_HEADER_BUSINESSTELEPHONE = "Work Phone"
' used as the sort order for the contact's sort orders
Public Const CONTACTGRID_HEADER_SORT_FILEAS = "FileAs"
Public Const CONTACTGRID_HEADER_SORT_LASTNAME = "LastName"
Public Const CONTACTGRID_HEADER_SORT_FIRSTNAME = "FirstName"
Public Const CONTACTGRID_HEADER_SORT_COMPANYNAME = "CompanyName"
Public Const CONTACTGRID_HEADER_SORT_BUSINESSTELEPHONE _
= "BusinessTelephoneNumber"
' defines the column numbers for the contact grid
Public Const CONTACTGRID_COL_FILEAS = 0
Public Const CONTACTGRID_COL_LASTNAME = 1
Public Const CONTACTGRID_COL_FIRSTNAME = 2
Public Const CONTACTGRID_COL_COMPANYNAME = 3
Public Const CONTACTGRID_COL_BUSINESSTELEPHONE = 4
' the index of the menubars for the contact grid's popup menu
Public Const CONTACTPOPUP_MENU_INDEX_NEW = 1
Public Const CONTACTPOPUP_MENU_INDEX_DELETE = 2
Public Const CONTACTPOPUP_MENU_INDEX_COPY = 3
Public Const CONTACTPOPUP_MENU_INDEX_SHOWAPPTS = 4
Public Const CONTACTPOPUP_MENU_INDEX_SAMECOMP = 5
Public Const CONTACTPOPUP_MENU_INDEX_BEAM = 6
' captions for the menubars for the contact grid's popup menu
Public Const CONTACTPOPUP_MENU_CAPTION_NEW = "New Contact"
Public Const CONTACTPOPUP_MENU_CAPTION_DELETE = "Delete Contact"
Public Const CONTACTPOPUP_MENU_CAPTION_COPY = "Copy Contact"
Public Const CONTACTPOPUP_MENU_CAPTION_SHOWAPPTS = "Appointments for Contact"
Public Const CONTACTPOPUP_MENU_CAPTION_SAMECOMP = "New Contact-Same Company"
Public Const CONTACTPOPUP_MENU_CAPTION_BEAM = "Beam Contact"
' key for the menubars
Public Const MENU_VIEW_CONTACTS = "CONTACTS"
Public Const MENU_VIEW_TASKS = "TASKS"
Public Const MENU_VIEW_APPOINTMENT = "APPOINTMENT"
' key for the menubars
Public Const MENU_VIEW_CAPTION = "View"
Public Const MENU_VIEW_CONTACTS_CAPTION = "Contacts"
Public Const MENU_VIEW_TASKS_CAPTION = "Tasks"
Public Const MENU_VIEW_APPOINTMENT_CAPTION = "Appointments"
' used as the captions for the appt grid
Public Const APPTGRID_HEADER_START = "Start"
Public Const APPTGRID_HEADER_SUBJECT = "Subject"
Public Const APPTGRID_HEADER_LOCATION = "Location"
Public Const APPTGRID_HEADER_SORT_START = "Start"
Public Const APPTGRID_HEADER_SORT_SUBJECT = "Subject"
Public Const APPTGRID_HEADER_SORT_LOCATION = "Location"
Public Const APPTGRID_COL_START = 0
Public Const APPTGRID_COL_SUBJECT = 1
Public Const APPTGRID_COL_LOCATION = 2
Public Const APPT_APPTGRID_ROWS = 14
Public Const APPTPOPUP_MENU_INDEX_NEW = 1
Public Const APPTPOPUP_MENU_INDEX_DELETE = 2
Public Const APPTPOPUP_MENU_INDEX_COPY = 3
Public Const APPTPOPUP_MENU_CAPTION_NEW = "New Appt"
Public Const APPTPOPUP_MENU_CAPTION_DELETE = "Delete Appt"
Public Const APPTPOPUP_MENU_CAPTION_COPY = "Copy Appt"
Public Const TASKGRID_COL_PRIORITY = 0
Public Const TASKGRID_COL_SUBJECT = 1
Public Const TASKGRID_COL_DUEDATE = 2
Public Const TASKGRID_HEADER_PRIORITY = "Priority"
Public Const TASKGRID_HEADER_SUBJECT = "Subject"
Public Const TASKGRID_HEADER_DUEDATE = "Due Date"
Public Const TASKGRID_HEADER_SORT_PRIORITY = "Importance"
Public Const TASKGRID_HEADER_SORT_SUBJECT = "Subject"
Public Const TASKGRID_HEADER_SORT_DUEDATE = "DueDate"
Public Const TASKPOPUP_MENU_INDEX_NEW = 1
Public Const TASKPOPUP_MENU_INDEX_DELETE = 2
Public Const TASKPOPUP_MENU_INDEX_COPY = 3
Public Const TASKPOPUP_MENU_INDEX_BEAM = 4
Public Const TASKPOPUP_MENU_CAPTION_NEW = "New Task"
Public Const TASKPOPUP_MENU_CAPTION_DELETE = "Delete Task"
Public Const TASKPOPUP_MENU_CAPTION_COPY = "Copy Task"
Public Const TASKPOPUP_MENU_CAPTION_BEAM = "Beam Task"
Public Const TASK_TASKGRID_ROWS = 13
' used to tell if the stylus is down...
Public Const ASYNCKEYSTATE_LEFTMOUSE_KEY = 1
Public Const MOUSEDOWN_RIGHTCLICK_TIMING = 0.5
Public Declare Function CreatePopupMenu Lib "Coredll" () As Long
Public Declare Function DestroyMenu Lib "Coredll" _
(ByVal hMenu As Long) As Long
Public Declare Function AppendMenu Lib "Coredll" Alias "AppendMenuW" _
(ByVal hMenu As Long, ByVal wFlags As Long, _
ByVal wIDNewItem As Long, ByVal lpNewItem As String) As Long
Public Declare Function TrackPopupMenuEx Lib "Coredll" _
(ByVal hMenu As Long, ByVal un As Long, ByVal n1 As Long, _
ByVal n2 As Long, ByVal hWnd As Long, lpTPMParams As Long) As Long
Public Declare Function GetAsyncKeyState Lib "Coredll" _
(ByVal vKey As Long) As Integer
Public Const MF_ENABLED = &H0&
Public Const MF_STRING = &H0&
Public Const TPM_TOPALIGN = &H0&
Public Const TPM_LEFTALIGN = &H0&
Public Const TPM_RETURNCMD = &H100&
Public Const MF_GRAYED = &H1&
Public Const MF_CHECKED = &H8&
Public Const MF_UNCHECKED = &H0&
Public Const MF_SEPARATOR = &H800&

Contacts Form

Add a form to the project and name it frmContact. Add a grid and a vertical scrollbar. Name the grid grdContact and leave the scrollbar its default name of Vscroll1.

Add nine command buttons, sizing and placing similar to Figure 6.2. Give them captions of #ab, cde, fgh, ijk, lmn, opq, rst, uvw, and xyz. Name them cmdAB, cmdCDE, cmdFGH, cmdIJK, cmdLMN, cmdOPQ, cmdRST, cmdUVW, and cmdXYZ, respectively. To get the buttons white, you need to change the Style property to vbButtonGraphical and the BackColor to WindowBackground.

These buttons are designed to allow users to jump to a particular contact within the sort order. For example, if the current sort order is LastName, tapping the FGH button will locate the grid to the first contact that has a LastName that begins with F.

Contact Form Level Variables

There are two form level variables for the Contact form:


Dim gContactRowData(13) As Long
Dim gstrContactSortOrder As String

The array, dimensioned with 13 elements, stores the OID for each contact displayed in the grid. The current sort order for the grid is stored in the string variable gstrContactSortOrder.

The Form_Load Event

The first method to explore is the Form_Load event (see Listing 6.7). The Contact form should be the first form loaded, so in it, we'll create the POOM object and Logon() to it. For development purposes, it will check if there are any contacts and if not, prompt you to create some random ones. The rest of the code does other initialization.

Listing 6.7 The Form_Load Event


Private Sub Form_Load()
Dim objContacts As PocketOutlook.Items
Dim intCol As Integer
' create the PocketOutlook application once and only once...
Set gobjPoom = CreateObject("PocketOutlook.Application")
' logon - can not use until Logon is called...
gobjPoom.Logon
' get all contacts
Set objContacts = gobjPoom.GetDefaultFolder(olFolderContacts).Items
' check to see if there are any contacts
If objContacts.Count = 0 Then
' if no contacts, prompt user (developer) to create some
If MsgBox("There are no contacts, would you like to add some?", _
vbYesNo, "Create Contacts") = vbYes Then
' create dummy contacts
MakeContacts
End If
End If
' set the default sort order to the FileAs column
gstrContactSortOrder = CONTACTGRID_HEADER_SORT_FILEAS
' one row in grid - for the header
Me.grdContacts.Rows = 1
' five columns in grid
Me.grdContacts.Cols = 5
' set the column widths
Me.grdContacts.ColWidth(CONTACTGRID_COL_FILEAS) = 1500
Me.grdContacts.ColWidth(CONTACTGRID_COL_LASTNAME) = 1500
Me.grdContacts.ColWidth(CONTACTGRID_COL_FIRSTNAME) = 1500
Me.grdContacts.ColWidth(CONTACTGRID_COL_COMPANYNAME) = 1500
Me.grdContacts.ColWidth(CONTACTGRID_COL_BUSINESSTELEPHONE) = 1500
' set the header row captions
Me.grdContacts.TextMatrix(0, CONTACTGRID_COL_FILEAS) = _
CONTACTGRID_HEADER_FILEAS
Me.grdContacts.TextMatrix(0, CONTACTGRID_COL_LASTNAME) = _
CONTACTGRID_HEADER_LASTNAME
Me.grdContacts.TextMatrix(0, CONTACTGRID_COL_FIRSTNAME) = _
CONTACTGRID_HEADER_FIRSTNAME
Me.grdContacts.TextMatrix(0, CONTACTGRID_COL_COMPANYNAME) = _
CONTACTGRID_HEADER_COMPANYNAME
Me.grdContacts.TextMatrix(0, CONTACTGRID_COL_BUSINESSTELEPHONE) = _
CONTACTGRID_HEADER_BUSINESSTELEPHONE
' set the row to 0 - so we can manipulate the header cells
Me.grdContacts.Row = 0
' set the fonts for the header to bold
For intCol = 0 To Me.grdContacts.Cols - 1
Me.grdContacts.Col = intCol
Me.grdContacts.CellFontBold = True
Next
' set the column back to 0
Me.grdContacts.Col = 0
End Sub

Let's dissect this method and look at different segments of it.

Initializing POOM

In the following code snippet, the variable objContacts is declared as PocketOutlook.Items to retain a reference to the Contacts folder items. The POOM object is created through the CreateObject statement; remember that the declaration for it, gobjPOOM, was declared as Public in the modGlobal module file. After the POOM object is created, it's initialized by called the Logon method.


Dim objContacts As PocketOutlook.Items
Dim intCol As Integer
' create the PocketOutlook application once and only once....
Set gobjPoom = CreateObject("PocketOutlook.Application")
' logon - can not use until Logon is called...
gobjPoom.Logon

Checking for Contacts and Creating Samples

Rather than just get a reference to a PocketOutlook.Folder, a reference is taken directly to the Items collection from the Folder object, as shown in the following code. This reference, set to objContacts, was declared in the preceding snippet as PocketOutlook.Items. The Count property is tested for zero and if so, users are prompted to create some contacts. If users answer Yes, the method MakeContacts is called to create the contacts. (We'll explore MakeContacts after discussion the Form_Load event.)

Note

If your Pocket PC creates a default contact or appointment, you may have to change the check of Count = 0. The HP Jornada will create a contact and a task after a hard reset.


' get all contacts
Set objContacts = gobjPoom.GetDefaultFolder(olFolderContacts).Items
' check to see if there are any contacts
If objContacts.Count = 0 Then
' if no contacts, prompt user (developer) to create some
If MsgBox("There are no contacts, would you like to add some?", _
vbYesNo, "Create Contacts") = vbYes Then
' create dummy contacts
MakeContacts
End If
End If

Setting the Sort Order

The default current sort order is stored to the variable gstrContactSortOrder. This value comes again from a Const from the modGlobal module:


' set the default sort order to the FileAs column
gstrContactSortOrder = CONTACTGRID_HEADER_SORT_FILEAS

Setting Up the Grid

Next, the grid is set up to have the correct number of rows and columns:


' one row in grid - for the header
Me.grdContacts.Rows = 1
' five columns in grid
Me.grdContacts.Cols = 5

Then the column widths are set:


' set the column widths
Me.grdContacts.ColWidth(CONTACTGRID_COL_FILEAS) = 1500
Me.grdContacts.ColWidth(CONTACTGRID_COL_LASTNAME) = 1500
Me.grdContacts.ColWidth(CONTACTGRID_COL_FIRSTNAME) = 1500
Me.grdContacts.ColWidth(CONTACTGRID_COL_COMPANYNAME) = 1500
Me.grdContacts.ColWidth(CONTACTGRID_COL_BUSINESSTELEPHONE) = 1500

The "virtual" headers are created:


' set the header row captions
Me.grdContacts.TextMatrix(0, CONTACTGRID_COL_FILEAS) = _
CONTACTGRID_HEADER_FILEAS
Me.grdContacts.TextMatrix(0, CONTACTGRID_COL_LASTNAME) = _
CONTACTGRID_HEADER_LASTNAME
Me.grdContacts.TextMatrix(0, CONTACTGRID_COL_FIRSTNAME) = _
CONTACTGRID_HEADER_FIRSTNAME
Me.grdContacts.TextMatrix(0, CONTACTGRID_COL_COMPANYNAME) = _
CONTACTGRID_HEADER_COMPANYNAME
Me.grdContacts.TextMatrix(0, CONTACTGRID_COL_BUSINESSTELEPHONE) = _
CONTACTGRID_HEADER_BUSINESSTELEPHONE

After the headers are created, they are made bold by moving to the first row (Row = 0) and then cycling through the columns and setting the font to bold:


' set the row to 0 - so we can manipulate the header cells
Me.grdContacts.Row = 0
' set the fonts for the header to bold
' set the fonts for the header to bold
For intCol = 0 To Me.grdContacts.Cols - 1
Me.grdContacts.Col = intCol
Me.grdContacts.CellFontBold = True
Next
' set the column back to 0
Me.grdContacts.Col = 0

Loading the Menu

Finally, the menu is populated:


' set up the menu
LoadMenu

Although the menu code is present in the code resources, see Chapter 4, "Working with Menu Controls for Pocket PC," for a description of menu functionality. If you don't want to implement the menu now, omit this code line or comment it out.

The MakeContacts Routine

The MakeContacts routine (see Listing 6.8) is designed to allow you to have a group of contacts that can be manipulated without affecting your actual contacts. If you plan to use MakeContacts, be sure that your device has been hard-reset and is configured in ActiveSync to not sync Contacts.

Listing 6.8 Making Sample Contacts


Sub MakeContacts()
Dim objContact As PocketOutlook.ContactItem
Dim objItemsContact As PocketOutlook.Items
Dim intContact As Integer
Dim intProperty As Integer
Dim intChar As Integer
Dim strLetter As String
' get the contact folder
Set objItemsContact = gobjPoom.GetDefaultFolder(olFolderContacts).Items
' seed the RND() function
Rnd Timer()
' add 100 contacts
For intContact = 1 To 100
' get the new contact
Set objContact = objItemsContact.Add()
' set 3 different properties
For intProperty = 1 To 3
' make a string up to 15 chars in length
For intChar = 1 To Int(Rnd() * 15)
' make the letter
strLetter = Chr((Rnd() * 26) + 63)
' is it alpha?
If strLetter >= "A" And strLetter <= "Z" Then
' which property are we setting
Select Case intProperty
Case 1
' set the FirstName property
objContact.FirstName = objContact.FirstName & strLetter
Case 2
' set the LastName property
objContact.LastName = objContact.LastName & strLetter
Case 3
' set the CompanyName property
objContact.CompanyName = objContact.CompanyName & strLetter
End Select
End If
Next
Next
' we need to ensure there is at least something
' in one of the Properties
If Len(objContact.FirstName & objContact.LastName) = 0 Then
objContact.FirstName = "Bob"
End If
' set the email property
objContact.Email1Address = objContact.FirstName & "@rtmobile.com"
' save the contact
objContact.Save
Next
End Sub

Let's dissect MakeContacts, covering the new ground.

First, a reference to the ContactFolder.Items is retrieved:


' get the contact folder
Set objItemsContact = gobjPoom.GetDefaultFolder(olFolderContacts).Items

The following snippet shows an abbreviated version of the loop that creates 100 contacts. An object reference to a newly created ContactItem is retrieved by calling the Add method from the Items collection. Remember that the Items collection is located on the Folder object.


' add 100 contacts
For intContact = 1 To 100
' get the new contact
Set objContact = objItemsContact.Add()
...
' save the contact
objContact.Save 
Next

Next, three properties are set from a randomly created string: FirstName, LastName, and CompanyName.


Case 1
' set the FirstName property
objContact.FirstName = objContact.FirstName & strLetter
Case 2
' set the LastName property
objContact.LastName = objContact.LastName & strLetter
Case 3
' set the CompanyName property
objContact.CompanyName = objContact.CompanyName & strLetter

Something important to remember before attempting to save a ContactItem is that one of the following properties must have a value: FirstName, LastName, FileAs, or CompanyName. A check is performed in the following code to ensure that the contact has a FirstName or LastName value set:


' we need to ensure there is at least something
' in one of the Properties
If Len(objContact.FirstName & objContact.LastName) = 0 Then
objContact.FirstName = "Bob"
End If
' set the email property
objContact.Email1Address = objContact.FirstName & "@rtmobile.com"

After all is well, the Contact is saved via the Save method:


' save the contact
objContact.Save

The Form_Activate Event

The Form_Activate event is used simply to refresh the contact grid. The method to refresh the grid is RefreshContacts:


Private Sub Form_Activate()
' refresh ALL contacts
RefreshContacts "
End Sub

The RefreshContacts function (see Listing 6.9) is the Contact form's meat-and-potatoes. It's responsible for finding the correct contacts, sorting, and displaying them.

Listing 6.9 The RefreshContacts Function


Public Function RefreshContacts(ByVal strSeek As String)
Dim objContact As PocketOutlook.ContactItem
Dim objItemsContact As PocketOutlook.Items
Dim intContact As Integer
Dim lngThisContact As Long
Dim strRestrict As String
Dim lngOIDFirstFound As Long
Dim lngFirstContactDisplayed As Long
On Error Resume Next
' get all contacts
Set objItemsContact = gobjPoom.GetDefaultFolder(olFolderContacts).Items
' sort by the current sort order - always ascending
objItemsContact.Sort "[" & gstrContactSortOrder & "]", False
' set the max for the scrollbar to be the top contact
' of the last "page" of contacts    Me.VScroll1.Max = objItemsContact.Count
- Me.VScroll1.LargeChange + 1
' if we have a seek parameter try to find
' the first contact meeting that parameter
If Len(strSeek) > 0 Then
' setup the restrict clause to be equal to or greater than
' the seek parameter
' this will find the next contact that meets the seek
' parameter if one does not exactly meet it
strRestrict = "[" & gstrContactSortOrder & _
"]>="" & " & strSeek & ""
' apply the seek
Set objContact = objItemsContact.Find(strRestrict)
' if we found a contact meeting the seek
' let's store the OID value (primary key - Outlook ID)
If Not objContact Is Nothing Then
' grab the OID
lngOIDFirstFound = objContact.oid
' start at the 1st contact
lngThisContact = 1
' cycle thru the contacts to find the contact's
' place in the sort order
' while we still looking at a valid contact
Do While lngThisContact <= objItemsContact.Count
' get the contact
Set objContact = objItemsContact.Item(lngThisContact)
' if it's our contact, let's get out
' lngThisContact will be the correct index of
' the contact found
If objContact.oid = lngOIDFirstFound Then
Exit Do
End If
lngThisContact = lngThisContact + 1
Loop
End If
Else
' if we don't have a seek value, use the scroll bar
' current value
lngThisContact = Me.VScroll1.Value
End If
' set the rows
Me.grdContacts.Rows = CONTACT_CONTACTGRID_ROWS
' save the index of the first contact displayed
' this is used to update the scroll bar with the correct
' position after we're done
lngFirstContactDisplayed = lngThisContact
' we don't clear the grid here, but just write over top of it
' this prevents less flickering and better performance
' if we don't use all the available rows, we just truncate them at the
end....
' we're going to cycle through the contacts
' and write them to the grid
For intContact = 0 To CONTACT_CONTACTGRID_ROWS - 1
' if we've gone past the last contact
' let's get out
' this happens when you start displaying contacts
' near the bottom - or when the first contact
' is closer to the bottom than the number of rows in the grid
If lngThisContact > objItemsContact.Count Then
Exit For
End If
' get the contact
Set objContact = objItemsContact.Item(lngThisContact)
' display the fields
Me.grdContacts.TextMatrix(intContact + 1, _
CONTACTGRID_COL_FILEAS) = objContact.FileAs
Me.grdContacts.TextMatrix(intContact + 1, _
CONTACTGRID_COL_LASTNAME) = objContact.LastName
Me.grdContacts.TextMatrix(intContact + 1, _
CONTACTGRID_COL_FIRSTNAME) = objContact.FirstName
Me.grdContacts.TextMatrix(intContact + 1, _
CONTACTGRID_COL_COMPANYNAME) = objContact.CompanyName
Me.grdContacts.TextMatrix(intContact + 1, _
CONTACTGRID_COL_BUSINESSTELEPHONE) = _
objContact.BusinessTelephoneNumber
' save the OID into the array
' this is used to do an action on the contact such as delete,
' copy, display, etc...
' we would use the Grid.RowData collection here, but there seems
' to be some bug that it will not take the value
gContactRowData(intContact + 1) = objContact.oid
' increment the index of the contact to be displayed
lngThisContact = lngThisContact + 1
Next
' if we displayed less contacts than the grid allows
' we need to truncate the dead rows
' the -1 and +1 accounts for the header row
If intContact < CONTACT_CONTACTGRID_ROWS - 1 Then
Me.grdContacts.Rows = intContact + 1
End If
End Function

RefreshContacts takes a single string parameter, strSeek:


Public Function RefreshContacts(ByVal strSeek As String)

This parameter is used when one button is tapped. It provides the criteria on which to seek in the current sort order. In other words, when the grid is sorted by Last Name and the fgh button is tapped, strSeek will have a value of F, meaning to start displaying contacts where the Last Name begins with F.

Now let's look at the functionality of RefreshContacts piece by piece.

Populating and Sorting the Grid Rows

Let's jump to the main loop that displays the Contacts and look at it:

' we're going to cycle through the contacts
' and write them to the grid

For intContact = 0 To CONTACT_CONTACTGRID_ROWS - 1
' if we've gone past the last contact
' let's get out
' this happens when you start displaying contacts
' near the bottom - or when the first contact
' is closer to the bottom than the number of rows in the grid

If lngThisContact > objItemsContact.Count Then

Exit For

End If
' get the contact

Set objContact = objItemsContact.Item(lngThisContact)
' display the fields