Alison Balteramp;#039;s Mastering Microsoft Office Access 1002003 [Electronic resources] نسخه متنی

Declaring and Assigning Object Variables

Object variables are variables that reference an object of a specific type, such as databases, recordsets, forms, controls, and even objects created in other applications. They allow you to create shortcut references to objects and pass objects to subroutines and functions. You can use them to streamline code by using short names to refer to objects with long names and to optimize code by supplying a direct pointer to a particular object.

First, you must declare an object variable; then you assignor

point the object variable to a particular object, as shown in the following code:

Private Sub cmdChangeCaption_Click()
'Declare a CommandButton object
Dim cmdAny As CommandButton
'Point the CommandButton object at the cmdHello Command button
Set cmdAny = Me.cmdHello
'Change the Caption of the control referenced by the cmdAny variable
cmdAny.Caption = "Hello"
End Sub

This code creates an object variable called cmdAny of the type CommandButton. You then use the Set statement to point your CommandButton object variable toward the cmdHello object on the current form, using the Me keyword. Finally, you modify the caption of the cmdAny object variable. Because an object variable is a reference to the original object, you're actually changing the caption of the cmdHello command button.

Object Variables Versus Regular Variables

The difference between object variables and regular variables is illustrated by the following code:

Dim intVar1 As Integer
Dim intVar2 As Integer
intVar1 = 5
intVar2 = intVar1
intVar1 = 10
Debug.Print intVar1 'Prints 10
Debug.Print intVar2 'Prints 5

This code uses ordinary variables. When you dimension these variables, each one is assigned a separate memory location. Although intVar2 is initially assigned the value of intVar1, changing the value of intVar1 has no effect on intVar2. This differs from the following code, which uses an object variable:

Private Sub Command5_Click()
Dim ctlText As TextBox
Set ctlText = Forms.frmSales.txtProductID
ctlText.Text = "New Text"
Debug.Print Forms.frmSales.txtProductID.Text 'Prints New Text
End Sub

This routine creates an object variable called ctlText of type TextBox. It then associates the object variable with Forms.frmSales.txtProductID. Next, it modifies the Text property of the object variable. Because the object variable is actually pointing to the text box on the form, the Debug.Print statement prints the new text value.

Generic Versus Specific Object Variables

Access supports the use of generic object variables, including Application, Control, Form, and Report. Generic object variables can be used to refer to any object of that generic type:

Private Sub ChangeVisible_Click()
Dim ctlAny As Control
Set ctlAny = Me.txtCustomerID
ctlAny.Visible = False
End Sub

In this example, ctlAny can be used to point to any control. Compare that with the following code:

Private Sub cmdChangeVisible_Click()
Dim txtAny As TextBox
Set txtAny = Me.txtCustomerID
txtAny.Visible = False
End Sub

Here, your object variable can be used only to point to a text box.

Cleaning Up After Yourself

When you're finished working with an object variable, you should set its value to Nothing. As used in the following example, this statement frees up all memory and system resources associated with the object

Set frmNew = Nothing